旧型
memwintest:
	mov	dx,53dh
	in	al,dx
	mov	ah,al
	and	ah,~04h		;後で使う時ようにbit2を落とす
	mov	[CS:memwin],ah
	cmp	al,0xff
	jne	Xe10

	push	es
	xor	ax,ax
	mov	es,ax
	mov	al,[es:5a7h]		;5A7hにすでに数値があるなら調査不要
	mov	[CS:memwin],al	;入れ忘れ!!Xe10じゃなければFFのまま続行してしまうよ
	pop	es
	cmp	al,02h
	je	RA2VRAM
	cmp	al,0
	jne	Xe10

RA2VRAM:;;why?????
	mov	dx,7fdbh
	in	al,dx
	and	al,40h
	cmp	al,40h
	je	memwintest2	;512KBが切り離されてないならそのまま続行
	mov	dx,43fh
	mov	al,80h
	out	dx,al		;512KB 切り離し無効 Cバスバンクメモリ無効 メモリ窓接続

memwintest2:
;	mov	dx,461h
;	mov	al,0eh		;8000にE000:0を出す ノーマルハイレゾ共用
;	out	dx,al

;	push	es
;	mov	ax,9000h
;	mov	es,ax
;	xor	bx,bx
;	mov	ax,[es:bx]	;9000:0にF000:0の中身が見えるかどうか
;	pop	es
;	cmp	ax,0ffffh
;	je	under286	;見えない機種はシャドウRAMなし機種確定 確定しない!!!


;	mov	al,[cs:Machinecheck2]
;	or	al,10h				;ｼｬﾄﾞｰRAMありフラグ
;	mov	[CS:Machinecheck2],al


	mov	al,08h
	out	37h,al
	out	50h,al
	
	jmp	$+2
	jmp	$+2

	cli

;	mov	ax,0cc00h
	mov	ax,[cs:memwin16]	;ハイレゾならEA00-EBFFまでをコピー
	mov	ds,ax
	mov	ax,5000h		;CC00-CDFFまでを7000-71FFにコピー
	mov	es,ax
	mov	cx,1000h		;本当は16kb見たい… でも後ろがつまってるのでアウト
	xor	si,si
	xor	di,di
rep	movsw

	mov	ax,0d700h
	mov	ds,ax
	mov	ax,5200h		;D700-DCFFを7200-77FFにコピー
	mov	es,ax			;D8=73 D9=74 DA=75 DB=76 DC=77
	mov	cx,3000h
	xor	si,si
	xor	di,di
rep	movsw

	mov	ax,0e600h
	mov	ds,ax
	mov	ax,5800h		;E600-E7FFを7800-79FFにコピー
	mov	es,ax
	mov	cx,1000h
	xor	si,si
	xor	di,di
rep	movsw

	mov	ax,0ee00h
	mov	ds,ax
	mov	ax,5a00h		;EE00を7a00にコピー
	mov	es,ax
	mov	cx,800h
	xor	si,si
	xor	di,di
rep	movsw



	mov	dx,53dh
	mov	al,0ffh
	and	al,~04h			;これを落とさないととにかく始まらない
	and	al,~40h			;ハイレゾではここを落とす
	out	dx,al				;全RAM有効化 286機でも一応死にはしない 単にCC00とD700とDC00にBIOSROM内の無駄なゴミが出てくるだけ
;EPSON機　PC-286VEではBBhを出すことになって暴走した


	mov	al,02h				;BIOS RAMは強制するつもり
	mov	[CS:memwin],al
	mov	dx,[cs:MemoryBank]
	mov	al,[cs:MemoryWindow]		;memory window to C-bank 8000:0000->C000:0000  9000:0->D000:0
	out	dx,al				;Hirezo E-bank	A000:0000->E000:0000

	cmp	al,0eh
	je	nosasibiosram		;ハイレゾではSASIは調べない

	mov	dx,53dh
	mov	al,0ffh
	and	al,~04h
	out	dx,al				;ノーマルでは全部出す 邪魔くさいのでここで出し直し

	mov	ax,8c00h
	mov	es,ax
	mov	bx,0123h
	mov	ax,[es:bx]
	mov	cx,ax
	not	cx
	and	cx,0fff0h		;ffffを拒否 2024-8-29
	mov	[es:bx],cx		;8c00:0123に書き込み
	mov	ax,0cc00h
	mov	es,ax
	mov	dx,[es:bx]		;cc00:0123から読み出し
	cmp	cx,dx
	je	ok_sasicheck		;一致したらRAM

	mov	al,08h
	or	[CS:Machinecheck],al		;フラグ追加 2024-6-24
	or	[CS:Machinecheck2],al		;DB00もかけないフラグを立てておく
	mov	al,[CS:Cardcheck]
	and	al,1
	cmp	al,1
	je	BIOSBIG4kb3
	mov	cx,09200h
	mov	[CS:ShadowRam],cx			;裏の場所は9200h-->>F200
	mov	cx,09300h
	mov	[CS:ShadowRam2],cx			;表を9300h-->>F300
	mov	al,02h
	jmp	noscsibiosram
BIOSBIG4kb3:
	mov	cx,09300h
	mov	[CS:ShadowRam],cx			;裏の場所は9300といいつつ恐らく空?
	mov	cx,09000h
	mov	[CS:ShadowRam2],cx			;表を9000に動かす ほぼ空の状態のF300にInt1Bフック部を置く
	mov	al,02h
	jmp	noscsibiosram		;一致しなかったらシステム領域のみRAM化可能機種 RA前期 RL前期(ハイレゾ時未チェック)

ok_sasicheck:
	mov	dx,8c00h
	mov	es,dx
	mov	[es:bx],ax		;変更してしまった8c00:0123を戻す

	mov	ax,9700h			;9700に出てくるものと
	mov	es,ax
	mov	ax,5200h			;7200hにコピーしたもの
	mov	ds,ax
	mov	cx,800h			;4kb比較
	xor	si,si
	xor	di,di
rep	cmpsw
	jne	nosasibiosram		;一致したらD7はRAM化済み
	xor	ax,ax
	mov	cx,800h
	xor	di,di
rep	scasw					;一致していても全部0ならROM
	or	cx,cx				;具体的には100ボードの後半4kbがD700にいる場合
	je	nosasibiosram		;全部0に初期化したばかりのRAMはありえなくはないけど…無視
	mov	ax,0ffffh
	mov	cx,800h
	xor	di,di
rep	scasw					;一致していても全部FFならROM
	or	cx,cx
	je	nosasibiosram

	mov	al,[CS:memwin]
	or	al,40h
	mov	[CS:memwin],al

nosasibiosram:
;	mov	ax,08c00h			;8C00に出てくるものと
	mov	ax,[cs:memwin16_2]		;ノーマル 8C00 ハイレゾ 8A00
	mov	es,ax
	mov	ax,5000h			;7000にコピーしたもの
	mov	ds,ax
	mov	cx,1000h			;8kbだけ比較
	xor	si,si
	xor	di,di
rep	cmpsw
	jne	nosoundbiosram		;一致したらCC-CF(CDまでしか見てないけど)はRAM化済み
	xor	ax,ax
	mov	cx,1000h
	xor	di,di
rep	scasw					;一致していても全部0ならROM
	or	cx,cx
	je	nosoundbiosram
	mov	ax,0ffffh
	mov	cx,1000h
	xor	di,di
rep	scasw					;一致していても全部FFならROM
	or	cx,cx
	je	nosoundbiosram
	mov	al,[CS:memwin]
	or	al,80h
	mov	[CS:memwin],al

nosoundbiosram:
;	mov	ax,0d800h
	mov	ah,[cs:memwinIDE]		;さっきコピーされたもの
	xor	al,al
	mov	es,ax
;	mov	ax,9800h
	mov	ah,[cs:memwinIDE2]		;IDE-BIOSの出てくる位置
	mov	ds,ax
	mov	cx,1000h			;8kb比較
	xor	si,si
	xor	di,di
rep	cmpsw
	jne	noidebiosram			;一致したらIDE部はRAM化済み
	xor	ax,ax
	mov	cx,1000h
	xor	di,di
rep	scasw					;一致していても全部0ならROM
	or	cx,cx
	je	noidebiosram
	mov	ax,0ffffh
	mov	cx,1000h
	xor	di,di
rep	scasw					;一致していても全部FFならROM
	or	cx,cx
	je	noidebiosram
	mov	al,[CS:memwin]
	or	al,10h
	mov	[CS:memwin],al

noidebiosram:
;	mov	ax,0dc00h
	mov	ah,[cs:memwinSCSI]		;さっきコピーされたもの
	xor	al,al
	mov	es,ax
;	mov	ax,9c00h
	mov	ah,[cs:memwinSCSI2]		;SCSI-BIOSの出てくる位置
	mov	ds,ax
	mov	cx,800h			;4kbだけ比較
rep	cmpsw
	jne	noscsibiosram		;一致したらSCSI部はRAM化済み
	xor	ax,ax
	mov	cx,800h
	xor	di,di
rep	scasw					;一致していても全部0ならROM
	or	cx,cx				;
	je	noscsibiosram		;
	mov	ax,0ffffh
	mov	cx,800h
	xor	di,di
rep	scasw					;一致していても全部FFならROM
	or	cx,cx
	je	noscsibiosram
	mov	al,[CS:memwin]
	or	al,20h
	mov	[CS:memwin],al

noscsibiosram:
	mov	al,[CS:memwin]
	mov	dx,53dh
	out	dx,al				;この状態が調査状態なのでそれを保存

	mov	al,09h				;パリティ戻して
	out	37h,al
	out	50h,al

	sti

	mov	dx,461h
	mov	al,0eh		;8000にE000:0を出す ノーマルハイレゾ共用
	out	dx,al

	push	es
	mov	ax,9000h
	mov	es,ax
	xor	bx,bx
	mov	ax,[es:bx]	;9000:0にF000:0の中身が見えるかどうか
	pop	es
	cmp	ax,0ffffh
	je	under286	;見えない機種はシャドウRAMなし機種確定 ここでなら確定する

	mov	al,[cs:Machinecheck2]
	or	al,10h				;ｼｬﾄﾞｰRAMありフラグ
	mov	[CS:Machinecheck2],al

	push	es
	xor	ax,ax
	mov	es,ax
	mov	al,[CS:memwin]
	mov	[es:5a7h],al		;0000:05A7hに調査結果保存

	mov	dx,53dh
	out	dx,al				;ちゃんと実行して戻しておく!

	pop	es
	jmp	Xe10

under286:
	mov	dx,[cs:MemoryBank]
	mov	al,0ch				;286機での調査は内蔵ROMが前に出ているかだけ RAMにはならない
	out	dx,al

	xor	ax,ax
	mov	[CS:memwin],al		;初期化

	mov	ax,0cc00h			;CC00に今出ているものと
	mov	es,ax
	mov	ax,5000h			;7000にコピーしたもの(CC00にさっきいたもの)
	mov	ds,ax
	mov	cx,2000h			;16kb比較
	xor	si,si
	xor	di,di
rep	cmpsw					;一致したら内蔵SOUND-ROMが前に出ていた
	jne	nosoundbiosrom
	mov	al,[CS:memwin]
	or	al,80h
	mov	[CS:memwin],al

nosoundbiosrom:
	mov	ax,0d700h			;D700に今出ているものと
	mov	es,ax
	mov	ax,5400h			;7400hにコピーしたもの(さっきD700にいたもの)
	mov	ds,ax
	mov	cx,800h			;4kb比較
	xor	si,si
	xor	di,di
rep	cmpsw
	jne	nosasibiosrom		;一致したらD7は内蔵ROMが出現していた
	mov	al,[CS:memwin]
	or	al,40h
	mov	[CS:memwin],al

nosasibiosrom:				;IDEは絶対にない!!!SCSIだけ調べる
;	mov	ax,0dc00h
	mov	ah,[cs:memwinSCSI]		;さっきコピーされたもの(さっきDC00にいたもの)
	xor	al,al
	mov	es,ax
;	mov	ax,9c00h
	mov	ah,0DCh			;SCSI-BIOSの出てくる位置 今DC00にいるもの
	mov	ds,ax
	mov	cx,800h			;4kbだけ比較
rep	cmpsw
	jne	noscsibiosrom		;一致したらSCSI部は内蔵ROMが出現している
	mov	al,[CS:memwin]
	or	al,20h
	mov	[CS:memwin],al

noscsibiosrom:
	mov	dx,53dh
	out	dx,al				;必要なものだけ出現

	mov	dx,[cs:MemoryBank]
	mov	al,[cs:OriginalWindow]	;元に戻して
	out	dx,al

	push	es
	xor	ax,ax
	mov	es,ax
	mov	al,[CS:memwin]
	mov	[es:5a7h],al		;0000:05A7hに調査結果保存 286機でも保存することにする 危なくないよ
	pop	es


	mov	dx,7fdbh
	in	al,dx
	and	al,40h
	cmp	al,40h
	je	memwintestend
	mov	dx,43fh
	mov	al,82h
	out	dx,al		;512KB 切り離し有効 Cバスバンクメモリ有効 メモリ窓封印
	ret
Xe10:
;ここでFFFF:0005に書き込みを行う 2024-5-23
	mov	dx,[cs:MemoryBank]
	mov	al,0eh
	out	dx,al

	push	es
	push	cs
	pop	ds
	mov	cx,9fffh
	mov	es,cx
	mov	si,hook1B_onFFFF
	mov	di,5
	mov	cx,11
rep	movsb

	mov	cx,9800h
	mov	es,cx
	xor	ax,ax
	xor	di,di
	mov	cx,7fffh
	shr	cx,1
sumcheck:
	add	ax,[es:di]
	add	di,2
	loop	sumcheck
	xor	ah,ah
	mov	cx,100h
	sub	cx,ax
	mov	[es:7ffeh],cl		;word

	xor	ax,ax
	xor	di,di
	mov	cx,7fffh
sumcheck2:
	add	al,[es:di]
	inc	di
	loop	sumcheck2
	xor	ah,ah
	mov	cx,100h
	sub	cx,ax
	mov	[es:7fffh],cl		;byte

	pop	es

	mov	al,[cs:memwin]
	mov	[cs:env53D],al

	mov	dx,[cs:MemoryBank]		;メモリ窓戻して
	mov	al,[cs:OriginalWindow]
	out	dx,al

	mov	al,[cs:Machinecheck2]
	or	al,10h				;ｼｬﾄﾞｰRAMありフラグ
	mov	[CS:Machinecheck2],al

	mov	dx,7fdbh
	in	al,dx
	and	al,40h
	cmp	al,40h
	je	memwintestend
	mov	dx,43fh
	mov	al,82h
	out	dx,al		;512KB 切り離し有効 Cバスバンクメモリ有効 メモリ窓封印
memwintestend:
	ret
