プログラムでCoolBar に子コントロールを追加する方法

◆概要

　このページは、Visual Basic 6.0において、プログラムでCoolBar に子コントロールを追加する方法について記載しています。

　CoolBar バンド に子コントロールを追加するには、 Controls.Add メソッドでcontainer引数を指定し、新しいコントロールにバンドの子プロパティを設定する必要があります。

◆詳細


　CoolBar バンド の子プロパティは、 CoolBar に含まれるコントロールでなければなりません。 したがって CoolBar コントロールのバンドに子コントロールを追加するために、 Add メソッドのcontainer引数を指定する必要があります。

　コントロール コレクション の Add メソッドに、次のように指定します。 

object.Add(ProgID, name, container)

この方法では、コントロールが自動的に表示されません。 したがって、コントロールを追加した後に、新しいコントロールに適切なバンドの子プロパティを設定します。 これによってコントロールが表示されます。

◆Sample


  1. 新しい標準 EXE プロジェクトを開始します。
  2. プロジェクト メニューのコンポーネントを選択し「 Microsoft Windows Common Controls-3 6.0(SP5)」を選択して、 OK をクリックします。
  3. Form1にCoolBar コントロールを配置します。 既定ではバンドは 3つです。
  4. 2 つのコマンド ボタンを Form1 に配置します。
  5. フォームのモジュールに次のコードを追加します。 
Private Sub Command1_Click()
    Dim MyCtrl As Object
    ' 最初のバンドにボタンを追加します。
    Set MyCtrl = Controls.Add( _
        "VB.CommandButton", "cmdTest", CoolBar1)
    MyCtrl.Caption = "Test Button"
    ' 最初のバンド上にセット
    Set CoolBar1.Bands(1).Child = MyCtrl
    
    ' ２番目のバンドにテキストボックスを追加します。
    Set MyCtrl = Controls.Add("VB.TextBox", "txtTest", CoolBar1)
    MyCtrl.Text = "Testing Text"
    ' ２番目のバンド上にセット
    Set CoolBar1.Bands(2).Child = MyCtrl

End Sub

Private Sub Command2_Click()
    Dim MyCtrl As Object
    
    ' 新しいバンドにチェックボックスを追加します。
    Set MyCtrl = Controls.Add("VB.CheckBox", "ckTest", CoolBar1)
    MyCtrl.Caption = "Check Test"
    
    ' バンドを追加
    CoolBar1.Bands.Add Child:=MyCtrl, Visible:=True
    ' バンドを拡張
    CoolBar1.Bands(CoolBar1.Bands.Count).Width = 1000

End Sub

  1. プロジェクトを実行し、Command1 をクリックします。 新しい CommandButton が最初のバンドに表示され、TextBox が 2つめのバンドに表示されます。
  2. Command2 をクリックします。4つめのバンドにCheckBox で追加されます。 コードにあるようにバンドの Width プロパティを設定すると、指定した範囲内でマウスでCoolBarのサイズが変更できるようになります。

実行結果


CoolBar実行結果



▼ページトップへ