配列を返すプロシージャを作成する方法

◆概要


このページは、Visual Basic 6.0で配列を返すプロシージャを作成する方法について記載しています。


プロシージャー名に配列変数を代入することで、戻り値として配列変数を返すプロシージャを作成できます。

次の例を実行する前に、Visual Basic 6.0のメニュー[表示]-[イミディエイトウィンドウ]（ショートカットCtrl+G）でイミディエイトウィンドウを表示させておいてください。 

Option Explicit

Private Function ReturnArray(intArraySize As Integer) As Integer()
'引数分のランダムな整数配列を返す関数
    
    Dim intCounter  As Integer
    Dim intResult() As Integer
    
    Randomize   '乱数を発生させる
    
    '引数分の配列を確保
    ReDim intResult(intArraySize - 1) As Integer
    
    '配列にランダムな整数を代入
    For intCounter = LBound(intResult) To UBound(intResult)
        intResult(intCounter) = Fix(Rnd * intArraySize)
    Next
    
    'プロシージャー名に配列を代入
    ReturnArray = intResult
    
End Function

Private Sub Command1_Click()
    Dim intArraySize     As Integer
    Dim intReturnValue() As Integer
    Dim intCounter       As Integer
    
    '配列のサイズ
    intArraySize = 10
    
    'プロシージャによって作成された配列を受け取る
    intReturnValue() = ReturnArray(intArraySize)
    
    '作成された配列をイミディエイトウィンドウに出力
    For intCounter = LBound(intReturnValue) To UBound(intReturnValue)
        Debug.Print intReturnValue(intCounter);
    Next
    
    Debug.Print
End Sub
　　

◆実行結果


イミディエイトウィンドウ



▼ページトップへ