◆概要
　この資料は、Microsoft Accessでユーザー アカウントとグループ アカウントの作成について記載しています。


UserおよびGroupオブジェクトを使うと、ユーザー アカウントおよびグループ アカウントの作成と管理を行うことができます。Userは、データベースにログオンできる個人を表すオブジェクトで、Groupは、Userオブジェクトの集まりです。


ユーザーをグループに追加するには、Userオブジェクトを既存のグループのUsersコレクションに追加します。または、GroupオブジェクトをUserオブジェクトのGroupsコレクションに追加し、そのユーザーにグループのグローバルな権限を与えます。

グループに設定した権限は、そのグループに所属するすべてのユーザーに自動的に与えられ、ユーザーに設定した権限は、そのユーザーアカウントにのみ適用されます。ユーザーのセキュリティ レベルは、そのユーザーまたはユーザーが所属するグループに割り当てられた権限の中で、最も制約の少ないものになります。たとえば、特定のデータベースオブジェクトに対して、ユーザーが所属しているグループに与えられている権限よりも高いレベルの権限がユーザーに与えられている場合は、ユーザーに与えられている権限が有効になり、グループに与えられている権限は無効になります。

次のプロシージャでは、グループアカウントとユーザーアカウントを新規に作成し、既存のグループアカウントに新規ユーザーを追加します。

Sub VPPromotion()
    
    Dim ws As Workspace
    Dim grpVp As Group, grpManager As Group
    Dim usr As user
    
    ' Vice Presidents グループ　アカウントを作成します。
    Set ws = DBEngine.Workspaces(0)
    Set grpVp = ws.CreateGroup("VicePress", "mmbhto101193")
    ws.Groups.Append grpVp
    ws.Groups.Refresh
    
    ' 既存のユーザー アカウントのインスタンスを作成し、
    ' このユーザーを新規のグループ アカウントに追加してから、
    ' 既存のグループ アカウントから削除します。
    Set usr = grpVp.CreateUser("Andrew Fuller")
    grpVp.Users.Append usr
    grpVp.Users.Refresh
    Set grpManager = ws.Groups("Managers")
    grpManager.Users.Delete "Andres Fuller"
    grpManager.Users.Refresh
    
    ' 新しい manager 用にユーザー アカウントを新規に作成します。
    Set usr = grpManager.CreateUser("Mary McCreary", "mbw1011", "Pwd")
    ws.Users.Append usr
    ws.Users.Refresh
    
    ' Managers グループにユーザーを追加します。
    ' 既にこのユーザーは、[ユーザー グループ]グループに追加されているので、
    ' このアカウントのインスタンスを作成しなければ、ユーザー グループに追加することは
    ' できません。
    Set usr = grpManager.CreateUser("Mary McCreary")
    grpManager.Users.Append usr
    grpManager.Users.Refresh
End Sub

参照　ユーザーおよびグループの詳細については、「14.2.1Accessユーザーレベルセキュリティ モデル」の「ユーザーとグループ」を参照してください。