.sceno 257
.title 地下渓谷を流れる河川
.oridark=1
.if count(5)==0
[
完全な闇の中にあなたは佇んでいます。
激しく水の流れる音が聞こえてきます。すぐそばに河川があるのでしょう。

あなたがもしも照明機器を持ち合わせているのであれば使用した方が賢明です。
.dark=1
.stop
]
地下渓谷の最下部にいます。
すぐ脇には地下河川があり、その流量たるや地上の河川に引けをとりません。
北西へすすめば河川の上流までいく事ができます。河川の下流へ進むことは残念ながらできなそうです。
.dark=0
.if count(207)==1
[
渓谷の上方からはロープが垂れてきています。これを登って行けば階段まで戻ることができるでしょう。
.stop
]
.stop









[words]
@みる
地下渓谷の最下部にいます。
すぐ脇には地下の河川があり、その流量たるや地上の河川に引けをとりません。
北西へすすめば河川の上流までいく事ができます。河川の下流へ進むことは残念ながらできなそうです。
.if count(207)==1
[
渓谷の上方からはロープが垂れてきています。これを登って行けば階段まで戻ることができるでしょう。
.drop
.stop
]
.drop
.stop

@河川を　みる
@河川を　しらべる
@川を　みる
@川を　しらべる
地下河川と思えないほどの大流量です。
北西の方角から流れてきており、登って上流までいくことができそうです。
川は南東へと続いて流れていきますが、歩いて下流へ進むことは困難そうです。
.stop


@渓谷を　みる
@渓谷を　しらべる
@谷を　みる
@谷を　しらべる
深く切り立った谷です。
なにか強力な力が働いて地下の巨大な岩盤を引き裂いた、という感じです。
脇には激しくながれる河川がありますが、この水の流れがさらに渓谷の下部を削り、
深く鋭い谷に仕上げていったのでしょう。
.stop

@水を　みる
@水を　しらべる
綺麗で澄んだ水です。地上から浸水し多くの土の層で濾過された結果、これほどの
澄んだ水になるのでしょうね。
.stop



@ロープを　とる
@魔法のロープを　とる
@ロープを　はずす
@魔法のロープを　はずす
@ロープを　ほどく
@魔法のロープを　ほどく
.if count(207)==1
[
引っぱってみたのですが、ちょっとやそっとでは取れないように結ばれています。
というより、そのくらいしっかり結んでいないと、そっちの方が問題でしょう。
.stop
]
あなたの目には映っているのかもしれませんが、私にはちょっと見当たりません。
.stop

@ロープを　みる
@ロープを　しらべる
@魔法のロープを　みる
@魔法のロープを　しらべる
.if count(207)==1
[
渓谷の上方からだらんと垂れています。
.stop
]
はて、どこにあるのでしょうか？
.stop


@さけぶ
@大声を　だす
@歌を　うたう
あなたの声は渓谷を鳴り響いていきました。
.stop


@ロープを　のぼる
@ロープを　あがる
@魔法のロープを　のぼる
@魔法のロープを　あがる
@うえ
@上
@上へ　いく
@上へ　あがる
.if count(207)==0
[
さて、どうやって登って行きましょうか…。いい方法はないでしょうかね。
]
.if count(weight)>>15
[
さすがにこれだけの荷物を抱えてこの渓谷を登っていくのは無理というものです。
どこかで荷物を減らしてからの方がよさそうですね。
.stop
]
.count(sleep)=+10
.gonext ug256
.stop

@しんすい
@しんすいする
.if count(33+632)==1
[
.count(69)=1
.gonext sea87
.stop
]
河川を下りたいのでしたら、まずボートに乗りましょう。
.stop

@およぐ
@河川へ　はいる
@川へ　はいる
もしもこの河川があなたが子供のころに遊んだ緩やかな流れのあの小川であれば、
それもいいのですけどね。
.stop


@川の水を　とる
@水を　とる
@河川の水を　とる
川の水を両手にすくって、のどを潤しました。
.stop

@河川の水を　空の水筒で　とる
@水を　空の水筒で　とる
@河川の水で　空の水筒を　みたす
@水で　空の水筒を　みたす
@川の水を　空の水筒で　とる
@川の水で　空の水筒を　みたす
.if item(11)==1
[
水筒いっぱいに川の水をくみました。
.item(11)=0
.item(26)=1
.stop
]
それではだめみたいです。
.stop

@釣りを　する
@魚を　つる
@釣り竿で　魚を　つる
.if count(627+12)==1
[
残念ながら、この川には魚はいないようです。
.stop
]
なにか道具が足りないののではありませんか？
.stop

@魚を　とる
残念ながら、この川には魚はいないようです。
.stop

@釣り竿で　魚を　とる
@釣り竿で　魚を　つかまえる
.if item(27)==1
[
残念ながら、この川には魚はいないようです。
.stop
]
言いたいことはわかるのですが、その場合はもう少し違った言い方をしませんか？
.stop




@ほくせい
@北西
@北西へ　いく
@北西へ　すすむ
@上流へ　いく
@上流へ　すすむ
.gonext ug258
.stop


















{words}

@みる
完全な闇の中にあなたは佇んでいます。
激しく水の流れる音が聞こえてきます。すぐそばに河川があるのでしょう。

あなたがもしも照明機器を持ち合わせているのであれば使用した方が賢明です。
.stop

@しんすい
@しんすいする
.if count(33+632)==1
[
.count(69)=1
.gonext sea87
.stop
]
河川を下りたいのでしたら、まずボートに乗りましょう。
.stop

@およぐ
@河川へ　はいる
@川へ　はいる
暗さ、音から判断できる河川の水の流量、速さ、どれを取ってしても、あまりにも
危険です。自殺するのと同じことですよ。
.stop
